Módulos, testes e leis
Slide 42 de 85
42testMódulos, testes e leis

Testes

Gramática: test-decl
testSTRINGblock
test-decl = "test" STRING block ;

Um teste é uma declaração de nível superior, test "o que ele mostra" { … }, nomeado em prosa porque o nome é documentação e não algo que alguém chama. Ele não recebe parâmetros e não responde nada — um return sozinho sai de um mais cedo — e um arquivo só com testes não precisa de main. O título é como o relatório o nomeia, então dois testes não podem ter o mesmo, nem dois títulos que diferem só num espaço em vez de um _.

hive test entrypoint.hive roda todo teste que o ponto de entrada alcança, sem framework e sem vocabulário além do assert, e termina com código diferente de zero quando algum falha, que é o que um hook de commit ou um passo de CI quer. Dentro de um teste:

  • um assert que falha é registrado com a condição como foi escrita e, para == ou !=, os dois lados — e o teste continua, então toda falha nele é listada;
  • um panic reprova só aquele teste, e o resto da suíte continua rodando;
  • o que um teste imprime com echo só aparece quando ele falha.

Toda execução reporta a cobertura — as instruções das suas próprias declarações, e quais delas nenhum teste alcançou, uma importada nomeada como o módulo dela a escreve. Uma falha aponta para o main_test.go gerado em vez da linha do .hive, o que é uma lacuna conhecida. Um teste roda com o diretório de trabalho no projeto gerado, e não na pasta do ponto de entrada, então um teste que precisa de arquivos os escreve ele mesmo.

Testes ao lado do código
type Item {
	name:  Str
	price: Int
}

func total(items: Item[]): Int {
	mut sum := 0
	for each item in items {
		sum = sum + item.price
	}
	return sum
}

test "um carrinho vazio não custa nada" {
	Item[0] empty = []
	assert total(empty) == 0
}

test "dois itens somam" {
	assert total([Item("wax", 5), Item("comb", 3)]) == 8
}
basket.hive, errado de propósito
func total(prices: Int[]): Int {
	mut sum := 0
	for each p in prices {
		sum += p
	}
	return sum
}

func unused(n: Int): Int {
	return n
}

test "uma cesta vazia não custa nada" {
	Int[0] empty = []
	assert total(empty) == 0
}

test "este está errado de propósito" {
	echo "aparece, porque este teste falha"
	assert total([3, 4]) == 8
	assert total([1]) == 2
}
Como uma falha aparece
$ hive test basket.hive
  PASS  uma cesta vazia não custa nada
  FAIL  este está errado de propósito
        aparece, porque este teste falha
        main_test.go:24: assert total([3, 4]) == 8
          left:  7
          right: 8
        main_test.go:27: assert total([1]) == 2
          left:  1
          right: 2

  2 tests: 1 passed, 1 failed
  coverage: 77.7% of statements (7/9)
  never exercised: unused