O módulo de UI

proc main(): void {
	view := hive.ui.column([hive.ui.pad(24), hive.ui.gap(12)], [
		hive.ui.text([hive.ui.size(hive.ui.TextSize.Title()), hive.ui.heading(1)], "Tour do Hive"),
		hive.ui.row([hive.ui.gap(8)], [
			hive.ui.input([hive.ui.placeholder("seu nome")], ""),
			hive.ui.button([hive.ui.tone(hive.ui.Tone.Good())], "Dizer oi"),
		]),
		hive.ui.link([hive.ui.background(hive.ui.Tone.Good())], "/1", "Começar →"),
	])

	body := hive.ui.page("Hive", view)   // um documento inteiro, servido diretamente
	echo len(body)
}

import hive.ui

type Model {
	rows:    Str[dyn]
	loading: Bool
}

type Msg {
	Refresh
	Loaded { rows: Str[dyn] }
}

func view(model: Model): ui.View {
	mut ui.View[dyn] kids = [ui.button([ui.on(Msg.Refresh())], "Atualizar")]
	if model.loading {
		append(kids, ui.spinner([]))
	}
	for each row in model.rows {
		append(kids, ui.text([], row))
	}
	return ui.column([ui.pad(24), ui.gap(8)], kids)
}

proc update(model: Model, msg: Msg, from: hive.syslink.Envelope): Model {
	if msg is Msg.Refresh {
		async reload(hive.syslink.self(from))   // lá vai; nada a segurar
		return Model(model.rows, true)           // ...e o spinner começa agora
	} else if msg is Msg.Loaded(rows) {
		return Model(rows, false)                // volta como uma mensagem
	}
	return model
}

proc reload(window: hive.syslink.Address): void {
	hive.task.sleep(400)
	async window(Msg.Loaded(["north", "south"]))
}

proc main(): void {
	ui.window("Colônias", view, update, Model([], false))
}

import hive.ui

type Model {
	posts: Str[dyn]
	draft: Str
}

func view(model: Model): ui.View {
	mut ui.View[dyn] kids = [
		ui.input([ui.placeholder("diga algo")], model.draft),
		ui.button([ui.disabled(model.draft == "")], "Publicar"),
	]
	for each post in model.posts {
		append(kids, ui.text([], post))
	}
	return ui.column([ui.pad(24), ui.gap(8)], kids)
}

test "o botão fica desabilitado até algo ser digitado" {
	empty := ui.html(view(Model([], "")))
	assert indexOf(empty, "disabled") is Result.Ok(_)

	typed := ui.html(view(Model([], "oi")))
	assert indexOf(typed, "disabled") is Result.Error(_)
}

test "o corpo de um post não contrabandeia markup para a página" {
	page := ui.html(view(Model(["<script>steal()</script>"], "")))
	assert indexOf(page, "<script>") is Result.Error(_)
}