A biblioteca padrão
Slide 48 de 85
48MapA biblioteca padrão

Mapas

hive.map.Map<K, T> é a única coleção que não é um vetor. Uma chave é comparada e tem seu hash calculado por inteiro, então é uma Str, Int, Float, Bool, Atom, ou um tipo declarado cujos campos sejam todos um desses. new() diz apenas "vazio", então tira o seu tipo de onde cai — uma declaração, um retorno ou um parâmetro — ou, ligado com :=, do primeiro uso depois que o diga, como set(m, "a", 1), e fica com ele.

  • set(m, key, value) e delete(m, key) escrevem em um mapa mut. Substituir um valor mantém o lugar da chave; apagar uma chave e defini-la de novo a move para o fim.
  • get(m, key) responde com um Result, cujo Error carrega false; has(m, key) pergunta o mesmo sem o valor.
  • keys(m) e values(m) são vetores novos na ordem em que as chaves foram definidas, o que faz um echo de um mapa sair igual em toda execução.
  • fromTable(t) e toTable(m) cruzam de e para uma Table de linhas de duas células, para um mapa de Str para Str. fromTable pula uma linha com menos de duas células, e uma chave dada duas vezes mantém o primeiro lugar e o último valor.

Um mapa não é indexado nem percorrido: m[0] e for each … in m são erros de compilação, e percorrer keys(m) é o caminho. O módulo é map para encurtar — map.keys(m) — e a função nativa map(values, f) continua sendo a nativa: uma chamada sobre o nome é o módulo, e uma chamada solta, a nativa. Um mapa não pode ser codificado nem enviado a um serviço; envie seus pares como um vetor de um tipo declarado para eles.

Definindo, obtendo e percorrendo
proc main(): void {
	mut hive.map.Map<Str, Int> counts = hive.map.new()
	hive.map.set(counts, "bees", 12)
	hive.map.set(counts, "hives", 3)

	if hive.map.get(counts, "bees") is Result.Ok(n) {
		echo n
	}
	echo hive.map.has(counts, "wasps")
	hive.map.delete(counts, "hives")
	echo hive.map.keys(counts)
	echo hive.map.values(counts)
}
Cruzando de e para uma Table
proc main(): void {
	mut hive.map.Map<Str, Str> labels = hive.map.new()
	hive.map.set(labels, "bees", "many")
	echo hive.map.toTable(labels)

	echo hive.map.get(hive.map.fromTable([["wasps", "few"]]), "wasps")
}