A biblioteca padrãoSlide 53 de 85
53JsonA biblioteca padrão
Um documento sem forma declarada
Um documento cuja forma não é declarada é um hive.json.JsonValue: uma união comum com as variantes String, Boolean, Int, Float, Array, Object e Null, desmontada com is como qualquer outra. O codec dele é o próprio documento, então "x" é lido como String("x") e escrito de volta como "x", e null, onde quer que esteja, é Null().
- Um número continua
IntouFloatdo jeito que foi escrito, então1.0sobrevive a uma ida e volta como1.0— embora um número inteiro grande demais para umIntchegue comoFloat. - Um
Objectguarda suas propriedades como umhive.map.Map<Str, JsonValue>na ordem em que o documento as escreveu, entãohive.map.getlê uma pelo nome; uma chave escrita duas vezes mantém o primeiro lugar e o último valor. - Um tipo declarado pode ter um campo
JsonValue, deixando aberta aquela parte de um documento que no resto é declarado. - Por guardar um mapa, um
JsonValuenão tem ordem própria: ordenar alguns pede um comparador.
Um documento sem declaração por trás
proc main(): void {
// Qualquer documento, desmontado como qualquer união.
text := "\{\"name\":\"ada\",\"tags\":[\"x\",1]}"
if hive.json.JsonValue.decode(text, hive.json.codec()) is Result.Ok(doc) {
if doc is hive.json.JsonValue.Object(properties) {
if hive.map.get(properties, "name") is Result.Ok(name) && name is hive.json.JsonValue.String(value) {
echo value
}
}
}
// E um montado à mão: as propriedades de um objeto são um map.
mut hive.map.Map<Str, hive.json.JsonValue> fields = hive.map.new()
hive.map.set(fields, "count", hive.json.JsonValue.Int(3))
echo encode(hive.json.JsonValue.Object(fields), hive.json.codec())
}Dá para editar este programa e rodá-lo aqui.Tab indenta, Esc sai do programa e Ctrl+Enter o roda.
null, e números como escritos
proc main(): void {
text := "\{\"a\": null, \"b\": [1, 1.0]}"
if hive.json.JsonValue.decode(text, hive.json.codec()) is Result.Ok(doc) {
echo encode(doc, hive.json.codec()) // o mesmo documento de volta
if doc is hive.json.JsonValue.Object(properties) {
if hive.map.get(properties, "a") is Result.Ok(a) && a is hive.json.JsonValue.Null {
echo "a é null"
}
}
}
}Dá para editar este programa e rodá-lo aqui.Tab indenta, Esc sai do programa e Ctrl+Enter o roda.