A biblioteca padrão
Slide 56 de 85
56imageA biblioteca padrão

Imagens

O hive.image.decode(data) lê os bytes de um arquivo PNG, JPEG, GIF ou WebP — vindos do hive.file.read, do hive.file.asset ou do corpo de uma resposta — para um Result<hive.image.Picture, hive.image.ImageError>. Um GIF ou WebP animado é o seu primeiro quadro.

Uma Picture é a sua largura, width, a sua altura, height, e os seus pixels: um UInt8[dyn] de quatro bytes por pixel — vermelho, verde, azul e alfa, sem multiplicar pelo alfa — linha por linha a partir do canto de cima à esquerda, então o pixel (x, y) começa em (y * width + x) * 4. Seja o que for que o arquivo guardava, é nisso que ele é lido, e todo índice nele é provado dentro dos limites como qualquer outro.

O hive.image.scale(picture, width, height) é a mesma imagem exatamente nesse tamanho. Cada pixel novo é a média dos que ele cobre, pesada pelo quanto cada um é opaco; uma imagem aumentada os repete. Manter as proporções é conta de quem chama: scale(p, 40, p.height * 40 / p.width).

Um ImageError carrega uma message: para algo que não é um arquivo desses, um cortado no meio, e um que diz ter mais de 100 milhões de pixels, recusado antes de qualquer parte dele ser decodificada.

Uma imagem feita no código, redimensionada e desenhada
// Uma imagem feita aqui em vez de lida de um arquivo: quatro por quatro, os
// pixels com quatro bytes cada — vermelho, verde, azul, alfa — do preto ao branco.
func gradient(): hive.image.Picture {
	mut UInt8[dyn] pixels = []
	for i := 0; i < 16; i++ {
		grey := UInt8(i * 17)
		append(pixels, grey)
		append(pixels, grey)
		append(pixels, grey)
		append(pixels, UInt8(255))
	}
	return hive.image.Picture(4, 4, pixels)
}

proc main(): void {
	picture := hive.image.scale(gradient(), 8, 4)
	shades := ["@", "%", "#", "*", "+", "=", "-", ":", "."]
	pixels := picture.pixels
	for y := 0; y < picture.height; y++ {
		mut line := ""
		for x := 0; x < picture.width; x++ {
			red := (y * picture.width + x) * 4
			if pixels bounds red {
				shade := Int(pixels[red]) * len(shades) / 256
				if shades bounds shade {
					line += shades[shade]
				}
			}
		}
		echo line
	}
}
Uma imagem que o programa carrega
proc main(): void {
	stored := hive.file.asset("logo.png")
	if stored is Result.Ok(data) {
		if hive.image.decode(data) is Result.Ok(logo) {
			echo "{logo.width} by {logo.height}"
		}
	} else if stored is Result.Error(why) {
		echo why.message
	}
}