A biblioteca padrão
Slide 58 de 85
58termA biblioteca padrão

O terminal

hive.term é o terminal, uma linha ou uma tecla de cada vez:

  • print(text) escreve uma Str na saída padrão exatamente como ela é, sem terminar a linha — um prompt, ou uma linha montada aos pedaços; println(text) escreve a Str e uma quebra de linha, como o echo faz com uma Str. status(text) escreve uma linha na saída de erro — o que um programa está fazendo, em oposição ao que lhe pediram, então redirecionar a resposta nunca leva o progresso junto.
  • read() espera uma linha de entrada e responde sem a quebra de linha. No fim da entrada ele responde com o que sobrou, e depois "" para sempre, então uma linha vazia e o fim parecem iguais.
  • readSecret() lê uma linha com o eco do terminal desligado, direto para um Secret<Str>, então responde com um Result<Secret<Str>, SecretError>. Interrompido no prompt, ele religa o eco e encerra o programa com código 130; sem terminal para desligar, lê a linha como ela vier.
  • readSecretBypass() é a mesma leitura em memória comum, como o bypass é para o hide, então responde com um Secret<Str> simples e não falha.
  • raw(on) liga ou desliga o modo cru: o que é digitado não aparece nem fica esperando a linha inteira, e Ctrl+C vira uma tecla em vez de encerrar o programa. Do jeito que o programa terminar — com um panic ou com exit também — o terminal volta a ser o que era.
  • readKey() espera uma tecla e responde com uma hive.term.Key: o name dela, o mesmo que o hive.ui dá — "a", "A", "Ctrl+C", "ArrowUp", "Enter" — e o text que ela digita, "" para uma tecla que edita ou move em vez de digitar. Uma colagem, no modo cru, é uma tecla só, chamada Paste, com tudo o que foi colado, então uma quebra de linha nela nunca é Enter.
  • size() é a largura e a altura da janela, width e height, em células.
  • isTerminal() diz se a saída de erro é uma pessoa e não um pipe ou um arquivo.
  • args() é a linha de comando, sem o nome do próprio programa.
  • exit(code) encerra o programa ali com aquele código — então um caminho que termina nele conta como encerrado.

raw, readKey e size respondem com um Result cujo hive.term.TermError é NotATerminal, Closed quando a entrada acabou, ou Io.

Um segredo, lido e depois guardado
proc main(): void {
	echo "Token da API:"
	typed := hive.term.readSecret()
	if typed is Result.Error(why) {
		echo "sem onde guardar: {why.message}"
	} else if typed is Result.Ok(token) {
		// Ninguém além desta conta consegue ler o arquivo, e isso já vale
		// antes do primeiro byte do token entrar nele.
		if hive.file.writeSecret("./token.txt", token) is Result.Error(why) {
			echo "não deu para guardar: {why.message}"
		}
	}
}
Perguntando sobre o próprio terminal
proc main(): void {
	echo hive.term.isTerminal()
	echo hive.term.args()
}
Teclas, uma de cada vez
proc main(): void {
	if hive.term.raw(true) is Result.Error(why) {
		echo "não há teclas para ler aqui: {why.message}"
		return
	}
	hive.term.println("Digite à vontade; Escape encerra.")
	mut going := true
	for ; going; {
		if hive.term.readKey() is Result.Ok(key) {
			hive.term.println("{key.name} digita [{key.text}]")
			going = key.name != "Escape"
		} else {
			going = false
		}
	}
}