A biblioteca padrão
Slide 60 de 85
60startA biblioteca padrão

Programas lado a lado

O exec e o attach esperam pelo programa que rodam. O hive.term.start(command, arguments, directory) inicia um e responde na hora com um Result<hive.term.Process, hive.term.ExecError>, e o startWith acrescenta uma camada de ambiente, como o execWith faz. Enquanto ele roda:

  • processReceiveLine(process) é a próxima linha que ele escreveu, assim que ele a escreve, e processReceive(process, bytes) no máximo essa quantidade de bytes do que já tiver chegado. A saída e os erros dele são um fluxo só, na ordem em que foram escritos.
  • processSend(process, text) escreve na entrada dele, e processCloseInput(process) encerra essa entrada, para um programa que lê até não haver mais nada.
  • processWait(process) espera ele terminar e responde com o código de saída; with timeout desiste da espera e não perde nada.
  • processKill(process) para ele e tudo o que ele iniciou, e responde quando ele tiver terminado. O código de saída então é -1.

Uma chamada que falha responde com um hive.term.ProcessError: Closed quando a saída dele acabou ou ele foi parado, Send ou Receive nos outros casos. Um programa iniciado pertence a quem o iniciou: o que restar dele é parado quando esse termina — com um panic, com exit e com uma interrupção também.

O exemplo inicia a si mesmo de novo — hive.file.executable() diz onde ele está — avisado pelo primeiro argumento de qual papel fazer, então não precisa de nada instalado.

Uma conversa com outro programa
// O programa iniciado é este mesmo de novo, avisado de qual papel fazer.
proc main(): void {
	args := hive.term.args()
	if args bounds 0 {
		if args[0] == "--echo" {
			for line := hive.term.read(); line != ""; line = hive.term.read() {
				echo "heard {line}"
			}
		}
		return
	}
	if hive.file.executable() is Result.Ok(me) {
		if hive.term.start(me, ["--echo"], "") is Result.Ok(other) {
			hive.term.processSend(other, "hello\n")
			if hive.term.processReceiveLine(other) is Result.Ok(answer) {
				echo answer
			}
			hive.term.processCloseInput(other)
			echo "it ended with status {hive.term.processWait(other)}"
		}
	}
}